local build = import 'build.libsonnet';
local images = import 'images.libsonnet';
local environment = import '../node_modules/@sigyl/jsonnet-drone-environment/environment.libsonnet';
local compose = import '../node_modules/@sigyl/jsonnet-compose/compose.libsonnet';
local util = import 'util.libsonnet';

function(
  name,
  buildSecrets,
  publicSecrets,
  secretSecrets
)
  {
    kind: 'pipeline',
    type: 'docker',
    name: 'deploy',
    clone: {
      disable: false,
      depth: 0,
    },
    services: [
      images.docker {
        privileged: true,
        volumes: [
          {
            name: 'dockersock',
            path: '/var/run',
          },
          {
            name: 'ca',
            path: '/etc/docker/certs.d',
          },
        ],
      },
    ],
    volumes: [
      {
        name: 'dockersock',
        temp: {},
      },
      {
        name: 'ca',
        host: {
          path: '/etc/docker/certs.d',
        },
      },
    ],
    steps:[
      compose(
        std.map(
          function(secret) util.printEnv('env-guacamole', secret),
          publicSecrets,
        )
      )
      (
        images.ssh {
          settings +: {
            script: [
              'rm -f env-guacamole',
            ],
          },
        },
      ) {
        name: 'print env',
      },
      images.scp(
        '/stack/guacamole'
      ),
      images.wait(15),
      build(buildSecrets),
      compose(
        std.map(
          function(secret) environment.envSet(secret),
          publicSecrets + secretSecrets,
        ),
      )(
        images.ssh  {
          name: 'deploy stack',
          settings +: {
            script +: 
            std.map(
              function(secret)
                'export %(env)s=$${%(env)s}' % {
                  env: environment.environment(secret)
                },
              secretSecrets + publicSecrets,
            ) + 
            [
              'set -e',
              "cd /stack/guacamole",
              'docker login $${LOCAL_DOCKER_REGISTRY} --username client --password "$${REGISTRY_PASSWORD}"',
              'sh pull.sh',
              'sh deploy.sh',
            ]
          }
        },
      ),
    ],
  }